Сборки PE от Xemom1 [Общая]

rem Проверка, не отключен ли носитель (если да, то отключаем Y:\ и Акронисы)
set "Smenu=%AppData%\Microsoft\Windows\Start Menu"
IF %PROCESSOR_ARCHITECTURE% == x86 (IF NOT DEFINED PROCESSOR_ARCHITEW6432 set OS=32) else (set OS=64)
if exist X:\I386 (set wp=%WinDir%\System32\wallpaper.jpg) Else (set wp=%WinDir%\web\Wallpaper\Windows\img0.jpg)
if %SystemDrive% NEQ X: exit
set /a FreeRam=64
rem Определение свободной памяти
for /f "usebackq skip=1 tokens=3 delims=: " %%i in (`RamStatus.exe`) do set /a FreeRam=%%i
set /a FreeRam=%FreeRam%/1024
if exist X:\Temp md B:\PePrograms\PePrograms
If not exist B:\PePrograms md B:\PePrograms
set UR=%Temp%\2k10\User
:: Check 2k10 disk (if not exist, unmount Y:\ and Wim-soft.wim)
for /f "tokens=1-5 delims=\ " %%a in ('subst') do (
if /i "%%e"=="2k10" if "%%a"=="Y:" if not exist %%d\ subst %%a /d)
if not exist Y:\ goto:ReMount
start /b nircmdc trayballoon "Внимание!" "Диск 2k10 доступен, подключать программы не нужно!" shell32.dll,25 15000
exit
:ReMount
if exist B:\PePrograms (PECMD MOUN ,B:\PePrograms,0) else (imagex.exe /unmount B:\PePrograms)>nul 2>&1
:next2
:: Поиск подключенного диска и старт
start /b /wait Reg Add "HKLM\SYSTEM\CurrentControlSet\Control\Windows" /v "ErrorMode" /t REG_DWORD /d "0x00000002" /f>nul 2>&1
for %%i in (C D E F G H I J K L M N O P Q R S T U V W) do @call:Search %%i
start /b nircmdc trayballoon "Внимание!" "Диск с программами не обнаружен!" shell32.dll,77 15000
exit
:Search
set var=1
for /f "tokens=1" %%a in ('dir /d %1:\2k10\Programs-2k10\Win2k78.bat') do set var=%%a>nul 2>&1
if %var% NEQ 0 exit /b
start /b /w SUBST Y: %1:\2k10\Programs-2k10>nul 2>&1
if %FreeRam% GTR 128 If exist Y:\User.Config\Sample\WallpaperCust.jpg copy /y Y:\User.Config\Sample\WallpaperCust.jpg %wp%
if exist B:\PePrograms (pecmd MOUN Y:\Wim-soft.wim,B:\PePrograms&&attrib +h B:\PePrograms\Microsoft.VC80.CRT.manifest /S /D) else (imagex /mount Y:\Wim-soft.wim 1 B:\PePrograms&&attrib +h B:\PePrograms\Microsoft.VC80.CRT.manifest /S /D)
7z.exe x -y Y:\Win2k78.7z -o"%Smenu%\..\Programs.2k10">nul 2>&1
DelLnk.exe "%AppData%\Microsoft\Windows\Programs.2k10\Programs-2k10">nul 2>&1
DelLnk.exe "%AppData%\Microsoft\Windows\Programs.2k10\Programs">nul 2>&1
move /y "%AppData%\Microsoft\Windows\Programs.2k10\Programs-2k10" "%Smenu%">nul 2>&1
move /y "%AppData%\Microsoft\Windows\Programs.2k10\Programs" "%Smenu%\Programs">nul 2>&1
attrib "%Smenu%\Programs-2k10" +s>nul 2>&1
attrib "%Smenu%\Programs" +s>nul 2>&1
rd /s /q "%AppData%\Microsoft\Windows\Programs.2k10">nul 2>&1
start /b /wait Reg Add "HKLM\SYSTEM\CurrentControlSet\Control\Windows" /v "ErrorMode" /t REG_DWORD /d "0x00000000" /f>nul 2>&1
If exist Y:\User.Config\*.7z for /r "Y:\User.Config" %%i in (*.7z) do 7z.exe x -y "%%~dpnxi" -o"%UR%\%%~ni">nul 2>&1
if exist "%UR%\User_All.reg" (if %SystemDrive% EQU X: reg import "%UR%\User_All.reg")
if exist "%UR%\Add_%OS%.reg" (if %SystemDrive% EQU X: reg import "%UR%\Add_%OS%.reg")
for /r "%UR%" %%a in (User_PE.bat) do @call "%%~dpnxa"
@call:delink
:ex
start /b nircmdc trayballoon "Поздравляю!" "Подключены программы с диска %1:\!" shell32.dll,25 15000
exit
:delink
if not exist Y:\Recovery\Active@Utilites\DiskEdi*.* @call:dl Active@*skEd
if not exist Y:\Recovery\Active@Utilites\DiskExp*.* @call:dl Active@*Expl
if not exist Y:\Recovery\Active@Utilites\DiskIma*.* @call:dl Active@*Imag
if not exist Y:\Recovery\Active@Utilites\FileRec*.* @call:dl Active@*Reco
if not exist Y:\Recovery\Active@Utilites\HDHEX-E*.* @call:dl Active@*HEX
if not exist Y:\Recovery\Active@Utilites\KillDisk.* @call:dl Active@*Kill
if not exist Y:\Recovery\Active@Utilites\PartMan.*  @call:dl Active@*Part
if not exist Y:\Recovery\Active@Utilites\Passwor*.* @call:dl Active@*Pass
if not exist Y:\Recovery\Active@Utilites\Undelete.* @call:dl Active@*Unde
if not exist Y:\Recovery\Active@Utilites\Uneraser.* @call:dl Active@*Uner
if not exist Y:\Recovery\Active@Utilites\UnFormat.* @call:dl Active@*UnFo
if not exist Y:\Recovery\Active@Utilites\VirtDisk.* @call:dl Active@*Virt
if %OS% equ 64 (goto :64) else (goto :32)
exit /b
:32
@call:dl Active@*HEX-Editor
@call:dl AdwCleaner
@call:dl Driver*Import*PE
@call:dl FlexHEX
@call:dl Hotfix*Uninstall
@call:dl MBR*Check
@call:dl MS*DaRT
@call:dl System*Restore*ERD
@call:dl TeamViewer
@call:dl UPX-X-Shell
@call:dl USB*Safely*Remove
@call:dl UsbIDCheck
exit /b
:64
@call:dl Acronis*TIEES
@call:dl Active@*HEX-Editor
@call:dl Active@*Virtual*Disk
@call:dl AdwCleaner
@call:dl AfuWin*
@call:dl C-Temp
@call:dl DialupPE
@call:dl Driver*Import*PE
@call:dl FlexHEX
@call:dl Hotfix*Uninstall
@call:dl MBR*Check
@call:dl MS*DaRT
@call:dl NetSetMan
@call:dl Opened*Files*View
@call:dl Scroll*Mouse
@call:dl Simple*Eye
@call:dl System*Restore*ERD
@call:dl SysTracer
@call:dl TeamViewer
@call:dl UPX-X-Shell
@call:dl USB*Safely*Remove
@call:dl UsbIDCheck
@call:dl Virtual*FDD
@call:dl ╤сЁюё*Cmos
exit /b
:dl
cd /d "%Smenu%\Programs-2k10"
For /f "usebackq delims=" %%a IN (`dir /b /s ".\%1*.lnk"`) do Del /f /q "%%~dpnxa"
exit /b